> 
# Analysis mit Maple
# Zunaechst ein Blick auf den Vorrat an eingebauten Funktionen:
> plot(abs(x),x);
> plot(exp(x),x=-1..1,-1..3);
> plot(tan(x),x,-5..5);
> plot([sin(x),sin(2*x),sin(3*x)],x=0..2*Pi,color=[red,blue,green]);
> plot(ln(x),x=0..2);
# Fuer Ingenieuranwendungen besonders wichtig ist die Heaviside-Funktion (auch Sprungfunktion genannt):
> plot(Heaviside(x),x,axes=BOXED);
# Differenzieren und Integrieren
> restart:
> y:=cos(2*x); # Unsere Ausgangsfunktion
> ya:=diff(y,x); # Ableitung der Ausgangsfunktion nach x
> yi:=int(y,x); # Unbestimmte Integration der Ausgangsfunktion
# Als Ergebnis der unbestimmten Integration gibt Maple nur eine Stammfunktion aus.
# Die Menge aller Stammfunktionen heisst unbestimmmtes Integral. Sie hat die Gestalt
> yi+C;
# Falls erforderlich, muss der Benutzer die Integrationskonstante (hier C) selbst hinzufuegen.
# Bestimmte Integrale
> restart:
> plot(cos(2*x),x=0..Pi/4); 
> int(cos(2*x),x); # unbestimmte Integration
> Int(cos(2*x),x=0..Pi/4); # bestimmte Integration ohne Auswertung
> int(cos(2*x),x=0..Pi/4); # bestimmte Integration mit Auswertung
# Das Ergebnis gibt den Flaecheninhalt unter der Kurve zwischen x=0 und x=Pi/4
> y:=sqrt(cos(x^3));
> plot(y,x=0..1,0..1);
> int(y,x); # Maple findet keine Stammfunktion
> i1:=Int(y,x=0..1);
> i2:=int(y,x=0..1);
# Wie man sieht, ist eine exakte Auswertung des bestimmten Integrals
# wegen der unbekannten Stammfunktion nicht moeglich.
# Es kann aber eine numerische Auswertung vorgenommen werden auf zwei Arten:
> evalf(i1);
> i3:=int(y,x=0..1.0);
# Hier noch Beispiele zur Verwendung der Heaviside-Funktion:
> restart:
> y:=-1/2+(1-x^2)*Heaviside(1-x^2);
> plot(y,x=-2..2);
> ya:=diff(y,x);
# Der Summand mit Dirac bezieht sich auf eine Deutung der Ableitung im
# Sinne der Distributionstheorie. Fuer Ingenieurzwecke koennen solche Terme in der
# Regel ignoriert werden. In der folgenden graphischen Darstellung treten sie nicht auf:
> plot(ya,x=-2..2,axes=boxed);
> yi:=int(y,x);
> plot(yi,x);
> plot([y,ya,yi],x=-2..2,color=[black,red,blue],axes=boxed);
# Gleichrichtung eines Wechselstroms:
> plot(sin(t)*Heaviside(sin(t)),t=-4..12,axes=boxed);